open Parser

module SSet = Set.Make(String)
module SMap = Map.Make(String)
module CSet = Set.Make(Char)

(* Nushell built-in commands and keywords *)
let nushell_builtins = [
  "alias"; "all"; "ansi"; "any"; "append"; "ast"; "attr";
  "bits"; "break"; "bytes";
  "cal"; "cd"; "char"; "chunk-by"; "chunks"; "clear"; "collect";
  "columns"; "commandline"; "compact"; "complete"; "config"; "const";
  "continue"; "cp";
  "date"; "debug"; "decode"; "def"; "default"; "describe"; "detect";
  "do"; "drop"; "du";
  "each"; "echo"; "encode"; "enumerate"; "error"; "every"; "exec";
  "exit"; "explain"; "explore"; "export"; "export-env"; "extern";
  "fill"; "filter"; "find"; "first"; "flatten"; "for"; "format"; "from";
  "generate"; "get"; "glob"; "grid"; "group-by";
  "hash"; "headers"; "help"; "hide"; "hide-env"; "histogram";
  "history"; "http";
  "if"; "ignore"; "input"; "insert"; "inspect"; "interleave"; "into";
  "is-admin"; "is-empty"; "is-not-empty"; "is-terminal"; "items";
  "job"; "join";
  "keybindings"; "kill";
  "last"; "length"; "let"; "let-env"; "lines"; "load-env"; "loop"; "ls";
  "match"; "math"; "merge"; "metadata"; "mkdir"; "mktemp"; "module";
  "move"; "mut"; "mv";
  "nu-check"; "nu-highlight";
  "open"; "overlay";
  "panic"; "par-each"; "parse"; "path"; "plugin"; "port"; "prepend"; "print"; "ps";
  "query";
  "random"; "reduce"; "reject"; "rename"; "return"; "reverse"; "rm";
  "roll"; "rotate"; "run-external";
  "save"; "schema"; "scope"; "select"; "seq"; "shuffle"; "skip"; "sleep";
  "slice"; "sort"; "sort-by"; "source"; "source-env"; "split"; "start";
  "stor"; "str"; "sys";
  "table"; "take"; "tee"; "term"; "timeit"; "to"; "touch"; "transpose";
  "try"; "tutor";
  "ulimit"; "umask"; "uname"; "uniq"; "uniq-by"; "unlet"; "update";
  "upsert"; "url"; "use";
  "values"; "version"; "view";
  "watch"; "where"; "which"; "while"; "whoami"; "window"; "with-env"; "wrap";
  "zip";
]

let builtin_set = lazy (SSet.of_list nushell_builtins)

let is_nushell_builtin cmd =
  SSet.mem cmd (Lazy.force builtin_set)

let dedup_entries entries =
  let key_of entry =
    match entry.switch with
    | Short c -> Printf.sprintf "-%c" c
    | Long l | Both (_, l) -> Printf.sprintf "--%s" l
  in
  let score entry =
    let sw = match entry.switch with Both _ -> 10 | _ -> 0 in
    let p = match entry.param with Some _ -> 5 | None -> 0 in
    let d = min 5 (String.length entry.desc / 10) in
    sw + p + d
  in
  let best = List.fold_left (fun acc e ->
    let k = key_of e in
    match SMap.find_opt k acc with
    | Some prev when score prev >= score e -> acc
    | _ -> SMap.add k e acc
  ) SMap.empty entries in
  let covered = SMap.fold (fun _ e acc ->
    match e.switch with
    | Both (c, _) -> CSet.add c acc
    | _ -> acc
  ) best CSet.empty in
  List.fold_left (fun (seen, acc) e ->
    let k = key_of e in
    if SSet.mem k seen then (seen, acc)
    else match e.switch with
    | Short c when CSet.mem c covered -> (seen, acc)
    | _ -> (SSet.add k seen, SMap.find k best :: acc)
  ) (SSet.empty, []) entries |> snd |> List.rev

let nushell_type_of_param = function
  | "FILE" | "file" | "PATH" | "path" | "DIR" | "dir" | "DIRECTORY"
  | "FILENAME" | "PATTERNFILE" -> "path"
  | "NUM" | "N" | "COUNT" | "NUMBER" | "int" | "INT" | "COLS" | "WIDTH"
  | "LINES" | "DEPTH" | "depth" -> "int"
  | _ -> "string"

let escape_nu s =
  if not (String.contains s '"') && not (String.contains s '\\') then s
  else begin
    let buf = Buffer.create (String.length s + 4) in
    String.iter (fun c -> match c with
      | '"' -> Buffer.add_string buf "\\\""
      | '\\' -> Buffer.add_string buf "\\\\"
      | _ -> Buffer.add_char buf c
    ) s;
    Buffer.contents buf
  end

let format_flag entry =
  let name = match entry.switch with
    | Both (s, l) -> Printf.sprintf "--%s(-%c)" l s
    | Long l -> Printf.sprintf "--%s" l
    | Short s -> Printf.sprintf "-%c" s
  in
  let typed = match entry.param with
    | Some (Mandatory p) | Some (Optional p) -> ": " ^ nushell_type_of_param p
    | None -> ""
  in
  let flag = "    " ^ name ^ typed in
  if String.length entry.desc = 0 then flag
  else
    let pad_len = max 1 (40 - String.length flag) in
    flag ^ String.make pad_len ' ' ^ "# " ^ entry.desc

let format_positional p =
  let name = String.map (function '-' -> '_' | c -> c) p.pos_name in
  let prefix = if p.variadic then "..." else "" in
  let suffix = if p.optional && not p.variadic then "?" else "" in
  let typ = nushell_type_of_param (String.uppercase_ascii p.pos_name) in
  Printf.sprintf "    %s%s%s: %s" prefix name suffix typ

let fixup_positionals positionals =
  (* Nushell rules: no required after optional, only one rest param *)
  List.fold_left (fun (saw_opt, saw_rest, acc) p ->
    if p.variadic then
      if saw_rest then (saw_opt, saw_rest, acc)
      else (true, true, p :: acc)
    else if saw_opt then
      (true, saw_rest, { p with optional = true } :: acc)
    else
      (p.optional, saw_rest, p :: acc)
  ) (false, false, []) positionals
  |> fun (_, _, acc) -> List.rev acc

let extern_of cmd_name result =
  let entries = dedup_entries result.entries in
  let cmd = escape_nu cmd_name in
  let positionals = fixup_positionals result.positionals in
  let pos_lines = List.map (fun p -> format_positional p ^ "\n") positionals in
  let flags = List.map (fun e -> format_flag e ^ "\n") entries in
  let main = Printf.sprintf "export extern \"%s\" [\n%s%s]\n" cmd (String.concat "" pos_lines) (String.concat "" flags) in
  let subs = List.map (fun (sc : subcommand) ->
    Printf.sprintf "\nexport extern \"%s %s\" [  # %s\n]\n"
      cmd (escape_nu sc.name) (escape_nu sc.desc)
  ) result.subcommands in
  String.concat "" (main :: subs)

let generate_extern = extern_of

let module_name_of cmd_name =
  let s = String.map (function
    | ('a'..'z' | 'A'..'Z' | '0'..'9' | '-' | '_') as c -> c | _ -> '-') cmd_name in
  s ^ "-completions"

let generate_module cmd_name result =
  let m = module_name_of cmd_name in
  Printf.sprintf "module %s {\n%s}\n\nuse %s *\n" m (extern_of cmd_name result) m

let generate_extern_from_entries cmd_name entries =
  generate_extern cmd_name { entries; subcommands = []; positionals = []; description = "" }