{
  inputs.nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";

  outputs =
    { self, nixpkgs }:
    let
      forAllSystems =
        f:
        nixpkgs.lib.genAttrs [ "x86_64-linux" "aarch64-linux" ] (
          system: f (import nixpkgs { inherit system; })
        );
    in
    {
      devShells = forAllSystems (pkgs: {
        default = pkgs.mkShell {
          packages = with pkgs.ocamlPackages; [
            dune_3
            ocaml
            angstrom
            angstrom-unix
            camlzip
            ppx_inline_test
            ocaml-lsp
            ocamlformat
            ocamlformat-rpc-lib
            utop
          ];
        };
      });

      packages = forAllSystems (pkgs: {
        default = pkgs.ocamlPackages.buildDunePackage {
          pname = "inshellah";
          version = "0.1";
          src = ./.;
          nativeBuildInputs = [ pkgs.git ];
          buildInputs = with pkgs.ocamlPackages; [
            dune_3
            ocaml
            angstrom
            angstrom-unix
            camlzip
          ];

          meta.mainProgram = "inshellah";
        };
      });

      nixosModules.default =
        {
          pkgs,
          lib,
          config,
          ...
        }:
        {
          imports = [ ./nix/module.nix ];
          programs.inshellah.package = self.packages.${pkgs.stdenv.hostPlatform.system}.default;
          programs.inshellah.snippet = ''
            let inshellah_complete = { |spans|
              let completions = inshellah complete ...$spans | from json
              # special case nix completions, for `nix run nixpkgs#..` type input
              let additional = if ($completions == null and
                ($spans | length) > 0 and $spans.0 == "nix") {
                $env.NIX_GET_COMPLETIONS = ($spans | length) - 1
                let nix_output = $spans | run-external $in | split row -r '\n' | str trim | skip 1
                let entries = $nix_output |
                  if (($in | length) < 6 and
                    ($spans | last) =~ "[a-zA-Z][a-zA-Z0-9_-]*#[a-zA-Z][a-zA-Z0-9_-]*") { 
                    hide-env NIX_GET_COMPLETIONS
                    $in | par-each { |e| { value: $e, description: (^nix eval $e --apply "f: f.meta.description") }}
                } else {
                  $in | each { |e| { value: $e, description: "" } }
                }
                $entries
              } else {
                null
              }
              $completions | append $additional
            }
            $env.config.completions.external = {
              enable: true
              max_results: 200
              completer: $inshellah_complete
            }
          '';
        };
    };
}