{
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    nix-systems.url = "github:nix-systems/default-linux";
    unf.url = "git+https://git.atagen.co/atagen/unf";
  };

  outputs =
    inputs:
    with inputs;
    let
      version = builtins.toString self.lastModified;
      forEachSystem =
        function:
        nixpkgs.lib.genAttrs (import nix-systems) (
          system: function nixpkgs.legacyPackages.${system} system
        );
    in
    {
      devShells = forEachSystem (
        pkgs: _: {
          default = pkgs.mkShell {
            packages = [
              pkgs.nushell
            ];
          };
        }
      );

      packages = forEachSystem (
        pkgs: _: {
          default = pkgs.callPackage ./nix/default.nix {
            inherit version;
          };
          docs = pkgs.callPackage unf.lib.pak-chooie {
            inherit self;
            projectName = "meat";
            newPath = "https://git.atagen.co/atagen/meat/src";
            modules = [
              self.nixosModules.meat
            ];
          };
        }
      );

      nixosModules.meat =
        {
          pkgs,
          lib,
          config,
          ...
        }:
        let
          cfg = config.programs.meat;
        in
        {
          imports = [ ./nix/module.nix ];
          programs.meat.package = self.packages.${pkgs.stdenv.hostPlatform.system}.default.overrideAttrs {
            differ = cfg.differ;
            monitor = cfg.monitor;
          };
        };

    };
}