{
  config,
  lib,
  pkgs,
  ...
}: let
  palette-hex = pkgs.lib.nix-rice.palette.toRgbHex pkgs.rice.palette;
in {
  programs.wlogout = {
    enable = true;
    layout = builtins.fromJSON (builtins.readFile ../dots/wlogout/layout);
    style = with palette-hex; (builtins.replaceStrings
      [
        "/usr/share/wlogout"
        "/etc/wlogout"
        "#WINBG"
        "#BTNCOL"
        "#BTNBG"
        "#BTNFOCUSBG"
        "#WINLOGO"
      ]
      [
        "${pkgs.wlogout}/share/wlogout"
        "${pkgs.wlogout}/etc/wlogout"
        util.bg
        bright.yellow
        util.bg
        normal.black
        (builtins.path {
          name = "winlogo";
          path = ../icons/winlogo.png;
          sha256 = "7c1ff96b553c7a7ca3a7b7cf8efe830ab7feea92355aed288a10ee7347c24108";
        })
      ]
      (builtins.readFile ../dots/wlogout/style.css));
  };
}
