{
  stdenv,
  fetchFromGitHub,
  lib,
  gnome-themes-extra,
  gtk-engine-murrine,
  gtk_engines,
}:
stdenv.mkDerivation rec {
  pname = "kanagawa-gtk-theme";
  version = "unstable-2023-05-20";

  src = fetchFromGitHub {
    owner = "Fausto-Korpsvart";
    repo = "Kanagawa-GKT-Theme";
    rev = "7b8ece4382533491e82f9b3d5552607f67a79999";
    sha256 = "sha256-Jtu04SKXk0wFRvx2Duz0YxHEWJ2sM8ZIT+dtdJqKykY=";
  };

  buildInputs = [
    gnome-themes-extra # adwaita engine for Gtk2
    gtk_engines # pixmap engine for Gtk2
  ];

  propagatedUserEnvPkgs = [
    gtk-engine-murrine # murrine engine for Gtk2
  ];

  installPhase = ''
    runHook preInstall
    mkdir -p $out/share/themes
    cp -a themes/Kanagawa-B $out/share/themes/Kanagawa
    runHook postInstall
  '';
}
